;
; HAMMERSCHER ENTWURF (BRIESEMEISTER-VERSION)
; ===========================================
;
; Nr. bei Wagner: 20a
; Name:           Hammerscher Entwurf (flächentreu/Brisemeister-Version)
; Autor:          Hammer, Petermanns Mitteilungen 1892
; Quelle:         Karlheinz Wagner, Kartographische Netzentwürfe, Leipzig 1949, S. 200ff.
; Richtung:       Direkttransformation

;
; Das Programm übernimmt die Koordinaten eines Punktes (x/y) und transformiert
; diese in einen Punkt (x'/y').
;
; x/y sind ebene Zielpunktkoordinaten, x'/y' geben die geogr. Breite und Länge
; der Position auf der Quell-Erdkugel, auf der der Zielpunkt gelesen werden
; kann.
;
; Maßstab und Berührungslänge werden abgefragt.
;
; Briesemeisters Version bedeutet, dass der Hammer in X-Richtung auf 100/175.
; gestaucht wird. So wurde der Briesemeister (1953) gerechnet. Die Schieflage des
; Briesemeister (Erde in 45°N 10°E) wird nicht von diesem Programm gerechnet, sie muss
; vielmehr vorher mit einer Metatransformation ausgeführt werden.
;
; Literatur:
; Wagner: Kartographische Netzentwürfe, Leipzig: Bibliographisches Institut 1949
; Fiala: Mathematische Kartographie, Berlin: Verlag Technik 1957
; Canters: Small-scale Map Projecion Design, London: Taylor 2002

; (C) Rolf Böhm 2005

; Benutzte Variablen
; ==================
;
; Die Variablennamen entsprechen weitgehend denen von Karlheinz Wagner,

;
; Laufende Koordinaten
;
	_name	Hammerscher~Entwurf~(für~Briesemeister)
	_var	phi		; Geographische Breite
	_var	lambda		; Geographische Länge
	_var	delta		; Poldistanz/geographisch, auch Schiefdistanz
	_var	psi		
	_var	alpha		
	_var	cx
	_var	cy
;
; Konstanten der Transformation
;
	_var	scale		; Kartenmaßstabszahl (also 1000000, nicht 1/1000000)
	_var	lambda0		; Geogr. Länge des Bildmittelpunktes
;
; x, y, x', y', Cx', Cy', °(, (°, pi, pi/2 etc. sind vordefinierte globale Konstanten
;
; Initialisierung
; ===============
;
	tstne	initial	077$
; Dialog
	pause	Hinweis:~Dieses~Programm~rechnet~eine~Vorwärtstransformation.\\Es~muss~mit~einer~direkt~arbeitenden~¶
                Projection~engine~abgearbeitet~werden.
	pause   Hinweis:~Dieses~Programm~berücksichtigt~nicht~die~Transformation~¶
                der~Erde~in~45°N~10°E~Schieflage~-~hierzu~rechne~man~vorher~eine~Metatransformation.
	input	scale	Maßstabszahl
	input	lambda0	Mittelpunktslänge~in~Grad
; Eingegebene Werte auf Min/Max bringen
	clip	scale	1	1E12
	clip	lambda0	-180	180
; Konstanten
	mov	cy	200
	div	cy	175
	root	cy	2
	mov	cx	1
	div	cx	cy	; reciprocal cy
; Programm ist initialisiert
	mov	initial	1
077$:

;
; SIMD-Laufbereich
; ================

;
; Lambda und Phi übernehmen
; -------------------------
;
	mov	lambda	x		; Geographische Länge
	mov	phi	y		; Geographische Breite
	sub	lambda	lambda0	
	cmod	lambda	-180	180

; x, y haben eine Doppelbedeutung:
; - einmal die vordefinierten RTA-Input-Koordinaten, also eigentlich Phi und Lambda,
; - dann aber auch die ebenen Kartenkoordinaten, die errechnet werden

;
; Umrechnung in Bogenmaß
; ----------------------
;
	mul	phi	°(
	mul	lambda	°(

; Netzentwurf rechnen
; -------------------
;
	mov	r0	phi		; delta berechnen
	cos	r0
	mov	r1	lambda
	div	r1	2
	cos	r1
	mul	r0	r1
	acos	r0
	mov	delta	r0

	mov	r2	phi		; alpha berechnen
	sin	r2
	mov	r3	delta
	sin 	r3
	div	r2	r3
	acos	r2
	mov	alpha	r2

	mov	r4	delta		; sin(delta/2)
	div	r4	2
	sin	r4

	mov	x	alpha		; x
	sin	x
	mul	x	r4
	mul	x	4

	mov	r5	lambda		; Vorzeichen von x ist das von lambda
	sgn	r5
	mul	x	r5	

	mov	y	alpha		; y
	cos	y
	mul	y	r4
	mul	y	2
;
; Briesemeister
; -------------
;
	mul	x	cx
	mul	y	cy
;
; Maßstab, Kartenmittelpunkt etc. einrechnen
; ------------------------------------------
;
	mul	x	Rx'		; Erdradius
	div	x	scale		; Kartenmaßstab
	add	x	Cx'

	mul	y	Ry'
	div	y	scale
	add	y	Cy'

;
; Schlussarbeiten
; ---------------
;
111$:
	mov	x'	x
	mov	y'	y
	exit
	_end