;
; HAMMERSCHER ENTWURF NACH WAGNER, EXPERIMENTALVERSION
; ====================================================
;
; Nr. bei Wagner: 20b, 20c
; Name:           Variationen des Hammerschen Entwurfs nach Wagner (Experimantalversion)
; Autor:          Hammer (Grundentwurf) und Wagner (Pollinie, Flächenregulierung)
; Quelle:         Karlheinz Wagner, Kartographische Netzentwürfe, Leipzig 1949, S. 205ff.
; Richtung:       Inverse Transformation
;
;          Ja, Kinder, das ist Assembler! So wurden die MI-V-Rechner
;          der ollen James-Bond-Filme programmiert. Nur habe ich versucht,
;          RTA etwas verständlicher, als die JCL der IBM 360 anzulegen ...
;
; Das Programm übernimmt die Koordinaten eines Punktes (x/y) und transformiert
; diese in einen Punkt (x'/y').
;
; x/y sind ebene Zielpunktkoordinaten, x'/y' geben die geogr. Breite und Länge
; der Position auf der Quell-Erdkugel an, auf der der Zielpunkt gelesen werden
; kann.
;
; Maßstab und Berührungslänge werden abgefragt.
;
; Wagner hat in seine Modifikationen des Hammerschen Entwurfs 4 Parameter eingerechnet:
;
;        K1: Einen Parallel, der die Pollängenlänge bestimmt,
;        K2: Einen Aussenmeridian, der die Umbezifferung im Meridian steuert, indem auf diesen der 180°-Meridian umbeziffert wird,
;        K3: Eine Breite, bis zu der die Flächenverzerrung kontrolliert wird und
;        K4: Eine vorgeschriebene Flächenverzerrung, die nicht überschritten werden darf.
;
; Dieses Programm rechnet den Entwurf exakt nach und gestattet, diese 4 Parameter zu variieren.
;
; Die Zielbildgeometrie wird dem Sekundäroperanden oder einem Fixbild entnommen.
;
; Literatur:
; Wagner: Kartographische Netzentwürfe, Leipzig: Bibliographisches Institut 1949
; Fiala: Mathematische Kartographie, Berlin: Verlag Technik 1957

; Der zugrundeliegende Entwurf ist der Hammer-Wagner-Entwurf im Wagner als Nr. 20c
; auf Seite 208 ff.

; ACHTUNG!!! DRUCKFEHLER IM WAGNER S. 209: ES MUSS IN DER ZEILE UNTER (13) STATT FALSCH
; ... y = lambda /   k wurzel(n m1 m2)
; RICHTIG HEISSEN:
; ... y =   2    /   k wurzel(n m1 m2)
; DAS LAMBDA IM ZÄHLER MUSS ALSO EINE 2 SEIN.

; (C) Rolf Böhm 2004

; Benutzte Variablen
; ==================

; Die Variablennamen entsprechen weitgehend denen von Karlheinz Wagner,

;
; Laufende Koordinaten
;
	_name	Hammerscher~Entwurf~nach~Wagner~(Experimentalversion)
	_var	phi		; Geographische Breite
	_var	lambda		; Geographische Länge
	_var	alpha		; Polarkoordinaten Winkel
	_var	delta		; Polarkoordianten Distanz
	_var	psi		; Parameter (eine Art phi)
	_var	delta0		; Mittelpunktslänge
	_var	t1		; temporär
	_var	t2		; temporär
	_var	scale		; Maßstabszahl
	_var	lambda0		; Mittelmeridianlänge
	_var	phi-pol		; Parallelkreis der die Pollinienlänge bestimmt
	_var	phi-lim		; Grenzbreite bis zu der die Flächenverzerrung kontrolliert wird
	_var	zfv		; zulässige Flächenverzerrung in Prozent
	_var	lambda-		; Letzte umbezifferte Länge
	_var	m1		; Das m1 von Wagner
	_var	m2		; Das m2 von Wagner
	_var	n		; Das n von Wagner
	_var	k		; Das k von Wagner
	_var	C5.62		; Das 5.6229 im Wagner bei Entwurf 20c
	_var	C2.61		; Das 2.6162 im Wagner bei Entwurf 20c
;
; x, y, x', y', Cx', Cy', Rx', Ry', °(, (°, pi, pi/2 etc. sind vordefinierte globale Konstanten
;
; Initialisierung
; ===============
;
	tstne	initial	077$
; Dialog
	input	scale	Hammerscher~Entwurf~nach~Wagner~(Experimentalversion)\\Maßstabszahl
	clip	scale	1	1E12

	input	lambda0	Mittelpunktslänge~in~Grad
	clip	lambda0	-180	180

	input	phi-pol	Wagner-Konfigurationsparameter~1/4\\Breite~des~Parallelkreises~der~die~Pollinienlänge~bestimmt~in~Grad~(0.0001...90)\\0~=~Standardwert~bei~Wagner:~65°
	tstne	phi-pol	$44
	mov	phi-pol	65
$44:
	clip	phi-pol	0.0001	90

	input	lambda-	Wagner-Konfigurationsparameter~2/4\\Meridian,~der~auf~180°~umbeziffert~wird~in~Grad\(0.0001...180)\\0~=~Standardwert~bei~Wagner:~60°
	tstne	lambda-	$46
	mov	lambda-	60
$46:
	clip	lambda-	0.0001	180

	input	phi-lim	Wagner-Konfigurationsparameter~3/4\\Breite~bis~zu~welcher~die~Flächenverzerrung~kontrolliert~wird~in~Grad~(0.0001...90)\\0~=~Standardwert~bei~Wagner:~60°
	tstne	phi-lim	$48
	mov	phi-lim	60
$48:
	clip	phi-lim	0.0001	90

	input	zfv	Wagner-Konfigurationsparameter~4/4\\Maximal~zulässige~Flächenverzerrung~in~Prozent~(0.0001...100)\\0~=~Standardwert~bei~Wagner:~20~%
	tstne	zfv	$50
	mov	zfv	20
$50:
	clip	zfv	0.0001	100
; in Bogenmass
	mul	phi-pol	°(
	mul	phi-lim	°(
	mul	lambda-	°(
; Konstanten (Konfigurationsvariablen) berechnen
	mov	t1	zfv
	div	t1	100		; Prozent
	add	t1	1
	div	t1	2
	acos	t1
	div	t1	phi-lim
	mov	m2	t1

	mov	t1	phi-pol
	sin	t1
	mov	t2	pi/2
	mul	t2	m2
	sin	t2
	div	t1	t2
	mov	m1	t1

	mov	t1	phi-pol
	div	t1	2
	sin	t1
	mul	t1	2
	mov	t2	lambda-
	div	t2	2
	sin	t2
	div	t1	t2
	root	t1	2
	mov	k	t1

	mov	t1	lambda-
	div	t1	pi
	mov	n	t1

	mov	t1	k
	mul	t1	2
	mov	t2	m1
	mul	t2	m2
	mul	t2	n
	root	t2	2
	div	t1	t2
	mov	C5.62	t1

	mov	t1	2
	mul	t2	k		; Root(n m1 m2) steht noch in t2 drin!
	div	t1	t2
	mov	C2.61	t1

; Programm ist initialisiert
	mov	initial	1
077$:
;
; SIMD-Laufbereich
; ================

;
; Maßstab, Kartenmittelpunkt etc. einrechnen
; ------------------------------------------

	sub	x	Cx'		; Bildmittelpunkt
	div	x	Rx'		; Erdradius
	mul	x	scale		; Kartenmaßstab

	sub	y	Cy'
	div	y	Ry'
	mul	y	scale
;
; Eigentlicher Entwurf, dieser invers
; -----------------------------------

; Für alpha und delta muss man ein kleines Gleichungssystem lösen

; alpha berechnen

	mov	t1	x
	mul	t1	C2.61
	mov	t2	y
;       mul        t2        2                ;??
	mul	t2	C5.62
	div	t1	t2
	atan	t1

	tstgt	y	$3		; Den doppeldeutigen atan quadrantenweise korrigieren
	tstgt	x	$1
	sub	t1	pi
	jump	$7
$1:
	add	t1	pi
	jump	$7
$3:
	tstgt	x	$5
	add	t1	0
	jump	$7
$5:
	add	t1	0
	jump	$7
$7:
	mov	alpha	t1		; alpha fertig

; delta berechnen

	mov	t1	y
	mov	t2	alpha
	cos	t2
;       mul        t2        2
	mul	t2	C2.61
	div	t1	t2
	asin	t1
	errjump	out
	mul	t1	2
	mov	delta	t1		; delta fertig

; psi berechnen (im regulären Hammer das phi)

	mov	t1	alpha
	cos	t1
	mov	t2	delta
	sin	t2
	mul	t1	t2
	asin	t1
	mov	psi	t1		; psi fertig

; phi berechnen (Diese Formel ist in 20c (b) gegenüber 20 neu eingeschoben: »Der Parameter«

	mov	t1	psi
	sin	t1
	div	t1	m1
	asin	t1
	errjump	out
	div	t1	m2
	mov	phi	t1

; lambda berechnen

	mov	t1	delta
	cos	t1
	mov	t2	psi
	cos	t2
	div	t1	t2
	acos	t1
	div	t1	n
	mov	lambda	t1
	tstgt	alpha	$13		; dem doppeldeutigen acos das Vorzeichen geben ...
	neg	lambda
$13:
; In Gradmaß umrechnen und Ausserhalbtest
; ---------------------------------------

	mul	phi	(°
	mul	lambda	(°
	cmplt	phi	-90	out
	cmpgt	phi	90	out
	cmplt	lambda	-180	out
	cmpgt	lambda	180	out
;
; Schlussarbeiten
; ---------------
;
	mov	x'	lambda
	mov	y'	phi
;       mul        y'        (°
;       mul        x'        (°
; Lambda um lambda0 kreisen lassen
	add	x'	lambda0
	cmod	x'	-180	180
	exit
out:
	mov	x'	-9999
	mov	y'	-9999
	exit
	_end